Timeline

Interactive Content

Use the following controls to compute an area decomposition using the early Sumerian metrology system appearing on VAT 12593:

Out[]=

​
multiple 1 2 3 4 5 6 7 8 9 base 600 60 10 1×600(rods)square3×60+2×10(bur)

Computational Explanation

Sumerian tablet VAT 12593 is the oldest securely datable mathematical table in the world. Its origin is the Sumerian city of Shuruppag in the northern part of Uruk, and it has been dated to 2600 BCE.

The tablet is ruled into three columns on front and back, where the first column gives a length measure in rods, the second the area measure corresponding to the squares of the numbers in the first column and the third column the area expressed in the early Sumerian units of iku, eshe and bur. Here, one rod square was an area approximately equal to 36 square meters and known as an (area) sar. Larger units 1 iku  100 sar, 1 eshe  6 iku and 1 bur  3 eshe were also defined.

The two smaller iku and eshe units had their own symbols that were repeated as many times as needed, while the larger unit bur had not only its own symbol but also separate symbols for 10 bur and 60 bur:

Out[]=

While the table appears to be a simple listing of field areas, it is actually closer to a multiplication table. This is because the sexagesimal place system from later periods had not yet been invented, meaning there was no abstract concept of numeration and numbers were regarded as attributes of objects rather than abstract concepts that could be operated on mathematically.

To see how the computation on VAT 12593 was performed and recorded, first build the list of values of each larger unit in terms of the area sar:

In[]:=

radixes=Reverse@FoldList[Times,{100,6,3}]

Out[]=

{1800,600,100}

In other words, 1 bur  1800 sar, 1 eshe  600 sar and 1 iku  100 sar. For example, consider the seventh row from the tablet:

Out[]=

… which reads:

Out[]=

4 × 60 (rods)

4 × 60 (rods) square

3 × 10 + 2 × 1 [bur]

Decomposing the area of 4 × 60 rods square gives:

In[]:=

NumberDecompose[(460)^2,radixes]

Out[]=

{32,0,0}

… i.e. 32 bur. Further decomposing 32 into its mixed-radix representation involving 60, 10 and 1 gives:

In[]:=

NumberDecompose[32,{60,10,1}]

Out[]=

{0,3,2}

As can be seen, this sequence of numbers corresponds to the pattern of symbols in the final column consisting of no 60-bur symbols, three 10-bur symbols and two 1-bur symbols.

To compute a full transcription of the table, write a few utility functions to perform the above decompositions and add some formatting:

In[]:=

times[l_]:=Riffle[l,"×"]

base60decompose[n_]:=With[{radix={60,10,1}},Riffle[times/@DeleteCases[Thread[{NumberDecompose[n,radix],radix}],{0,_}],"+"]]

FormatSumerianUnits[l_]:=Module[{res=Flatten[Riffle[DeleteCases[Thread[{l,{"(bur)","(eshe)","(iku)"}}],{0,_}],"+"]]},​​Row[If[l[[1]]==0,res,Flatten[res/.i_Integerbase60decompose[i]]]," "]​​]

For example, for the row of the table illustrated previously:

In[]:=

FormatSumerianUnits[{32,0,0}]

Out[]=

3×10+2×1(bur)

Applying these functions to the sequence of side lengths considered on the tablet produces a transcription:

In[]:=

TextGridTable[{​​Row[Append[times[length],If[length==={1,600}," rods"," (rods)"]]],​​Row[Append[times[length]," (rods) square"]],​​FormatSumerianUnits[NumberDecompose[(Times@@length)^2,radixes]]},​​{length,Join[{{1,600}},Table[{n,60},{n,9,1,-1}],Table[{n,10},{n,5,1,-1}]]}],



Out[]=

1×600 rods	1×600 (rods) square	3×60+2×10(bur)
9×60 (rods)	9×60 (rods) square	2×60+4×10+2×1(bur)
8×60 (rods)	8×60 (rods) square	2×60+8×1(bur)
7×60 (rods)	7×60 (rods) square	1×60+3×10+8×1(bur)
6×60 (rods)	6×60 (rods) square	1×60+1×10+2×1(bur)
5×60 (rods)	5×60 (rods) square	5×10(bur)
4×60 (rods)	4×60 (rods) square	3×10+2×1(bur)
3×60 (rods)	3×60 (rods) square	1×10+8×1(bur)
2×60 (rods)	2×60 (rods) square	8×1(bur)
1×60 (rods)	1×60 (rods) square	2×1(bur)
5×10 (rods)	5×10 (rods) square	1×1(bur)+1×1(eshe)+1×1(iku)
4×10 (rods)	4×10 (rods) square	2(eshe)+4(iku)
3×10 (rods)	3×10 (rods) square	1(eshe)+3(iku)
2×10 (rods)	2×10 (rods) square	4(iku)
1×10 (rods)	1×10 (rods) square	1(iku)

… which exactly reproduces the transcription given by Robson (2007, p. 74).

Additional Reading

• Chrisomalis, S. "Mesopotamian Systems." Ch. 7 in Numerical Notation: A Comparative History. Cambridge, England: Cambridge University Press, pp. 228–258, 2010.
• Deimel, A. No. 82 in Die Inschriften von Fara, II: Schultexte aus Fara. Wissenschaftliche Veröffentlichungen der Deutschen Orient Gesellschaft, No. 43. Leipzig, Germany: J. C. Hinrichs, 1923.
• George, A. R. Babylonian Topographical Texts. Orientalia Lovaniensia Analecta 40. Leuven: Peters, p. 119, 1993.
• Neugebauer, O. and Sachs, A. (Ed.). "Metrology." Ch. 1, § 4 in Mathematical Cuneiform Texts. New Haven, CT: American Oriental Society and the American Schools of Oriental Research, pp. 4–10, 1945.
• Nilson, H.; Damerow, P.; and Englund, R. K. Fig. 119 in Archaic Bookkeeping. Chicago, IL: University of Chicago Press, 1993.
• Nissen, H. J. P.; Damerow, P.; and Englund, R. K. Archaic Bookkeeping: Early Writing and Techniques of Economical Administration in the Ancient Near East. Chicago: University of Chicago Press, pp. 30–33, 1993.
• Powell, M. A. "Mathematik." In Reallexikon der Assyriologoe und vorderasiatischen Archäologie, Vol. 7 (Ed. D. O. Edzard). Berlin/New York: de Gruyter, pp. 457–530, 1990.
• Robson, E. "Tables and Tabular Formatting in Sumer, Babylonia, and Assyria, 2500 BCE–50 CE." Ch. 1 in The History of Mathematical Tables: From Sumer to Spreadsheets (Ed. M Campbell-Kelly, M. Croarken, R. Flood and E. Robson). Oxford, England: Oxford University Press, Fig. 1.3 and pp. 27–31, 2007.
• Robson, E. "Mesopotamian Mathematics." Ch. 2 in The Mathematics of Egypt, Mesopotamia, China, India, and Islam: A Sourcebook (Ed. V. J. Katz). Princeton, NJ: Princeton University Press, pp. 70–75, 2007.

Additional Links

• Cuneiform Digital Library Initiative: P010678
• Vorderasiatisches Museum: VAT 12593